#file morris_lecar_synapse.ode
#Morris-Lecar model of synpase at excitable barnacle muscle fiber
#adapted from Morris and Lecar (1981) Biophysical Journal 35 pp. 193-231
#Figure 8.9

par C=20 
par gbarCa=4.4 
par ECa=120
par gbarK=8 
par EK=-84
par gleak=2 
par Eleak=-60
par v1=-1.2
par v2=18 
par v3=2
par v4=30
par phi=0.04
par tau=0.8

par Iapplied=0

par gsyn=1 
par Esyn=150 
par alpha=1
par beta=0.12
par Tmax=1
par Vsynstar=27

#model equations
mpre_inf = (0.5*(1+tanh((Vpre-v1)/v2)))
wpre_inf = (0.5*(1+tanh((Vpre-v3)/v4)))

mpost_inf = (0.5*(1+tanh((Vpost-v1)/v2)))
wpost_inf = (0.5*(1+tanh((Vpost-v3)/v4)))

Tr=Tmax*heav(Vpre-Vsynstar)

Vpre' = (1/C)*(gbarCa*mpre_inf*(ECa-Vpre) + gbarK*wpre*(EK-Vpre) + gleak*(Eleak-Vpre))
wpre' = phi*(wpre_inf-wpre)/(tau)
ssyn' = alpha*Tr*(1-ssyn) - beta*ssyn
Vpost' = (1/C)*(gbarCa*mpost_inf*(ECa-Vpost) + gbarK*wpost*(EK-Vpost) + gleak*(Eleak-Vpost)+gsyn*ssyn*(Esyn-Vpost))
wpost' = phi*(wpost_inf-wpost)/(tau)


# initial condition
init Vpre=-10, wpre=0.0149, ssyn=0, Vpost=-60.85, wpost=0.0149

# final time
@ total=200
# set the plotting window size:
@ xlo=0, xhi=200, ylo=-65, yhi=40

# run the simulation in the GUI by selecting (I)nitialconds|(G)o
# plot species Vpost by selecting (G)raphic stuff|(A)dd curve and
# assigning the y-axis
done